ホームページ＞開発ツール＞Xojo / Real Studio Trial and Error・CocoaのDeclareでツールバーを実装する・コントロールの追加 - 別稿

• Window1のメソッドを以下の通り書き換え

  Private Shared Function setToolItemSearch(itemIdentifier As String) as Ptr
    // 文字列を指定してクラスオブジェクト／セレクタを取得する。最初に一回宣言しておけばよい。
    Declare Function NSClassFromString Lib "Cocoa" (aClassName As CFStringRef) As Ptr
    Declare Function NSSelectorFromString Lib "Cocoa" (aSelName As CFStringRef) As Ptr
    
    Declare Function alloc Lib "Cocoa" Selector "alloc" (receiver As Ptr) As Ptr
    
    Dim search1 As Ptr = NSClassFromString("NSSearchField")
    search1 = alloc(search1)
    Declare Function initWithFrame Lib "Cocoa" Selector "initWithFrame:" (receiver As Ptr, identifier As NSRect) As Ptr
    search1 = initWithFrame(search1, NSMakeRect(0,0,150,24))
    Declare Sub setDelegate Lib "Cocoa" Selector "setDelegate:" (receiver As Ptr, id As Ptr)
    setDelegate(search1, makeDelegateTextView(SearchToolbarItemIdentifier))  // Delegateの設定（retunキー、deleteキーが押された時をアクションとして認識するため）
    
    Dim toolbarItem As Ptr = NSClassFromString("NSToolbarItem")
    toolbarItem = alloc(toolbarItem)
    Declare Function initWithItemIdentifier Lib "Cocoa" Selector "initWithItemIdentifier:" (receiver As Ptr, identifier As CFStringRef) As Ptr
    toolbarItem = initWithItemIdentifier(toolbarItem, itemIdentifier)
    
    Declare Sub setLabel Lib "Cocoa" Selector "setLabel:" (receiver As Ptr, label As CFStringRef)
    setLabel(toolbarItem, "NSSearchField")
    Declare Sub setPaletteLabel Lib "Cocoa" Selector "setPaletteLabel:" (receiver As Ptr, label As CFStringRef)
    setPaletteLabel(toolbarItem, "Search")
    Declare Sub setToolTip Lib "Cocoa" Selector "setToolTip:" (receiver As Ptr, text As CFStringRef)
    setToolTip(toolbarItem, "Search Your Document")
    
    Declare Sub setView Lib "Cocoa" Selector "setView:" (receiver As Ptr, actionTarget As Ptr)
    setView(toolbarItem, search1)
    
    // Target/Actionは、NSSearchFieldCellのsearchButtonCellに対して設定する。
    Declare Function cell Lib "Cocoa" Selector "cell" (receiver As Ptr) As Ptr
    Dim cell1 As Ptr = cell(search1)
    Declare Sub setSendsWholeSearchString Lib "Cocoa" Selector "setSendsWholeSearchString:" (receiver As Ptr, flag As Boolean)
    setSendsWholeSearchString(cell1, false)  // false:虫眼鏡ボタンが有効に, true:虫眼鏡ボタンが無効に（この解釈でいいか？）
    Declare Function searchButtonCell Lib "Cocoa" Selector "searchButtonCell" (receiver As Ptr) As Ptr
    Dim searchButtonCell1 As Ptr = searchButtonCell(cell1)
    Declare Sub setTarget Lib "Cocoa" Selector "setTarget:" (receiver As Ptr, actionTarget As Ptr)
    setTarget(searchButtonCell1, makeTarget(itemIdentifier))  // Actionの受け口となるメソッドを定義
    Declare Sub setAction Lib "Cocoa" Selector "setAction:" (receiver As Ptr, actionEvent As Ptr)
    setAction(searchButtonCell1, NSSelectorFromString("action:"))
    
    Declare Sub refusesFirstResponder Lib "Cocoa" Selector "setRefusesFirstResponder:" (receiver As Ptr, flg As Boolean)  // NSControlのメソッド
    refusesFirstResponder(search1,true)
    
    return toolbarItem
  End Function
  

• Window1に以下のメソッドを追加（復活）

  Private Shared Function makeDelegateTextView(name As String) as Ptr
    // 文字列を指定してクラスオブジェクト／セレクタを取得する。最初に一回宣言しておけばよい。
    Declare Function NSClassFromString Lib "Cocoa" (aClassName As CFStringRef) As Ptr
    Declare Function NSSelectorFromString Lib "Cocoa" (aSelName As CFStringRef) As Ptr
    
    // Declare宣言
    Declare Function objc_allocateClassPair Lib "Cocoa" (superclass As Ptr, name As CString, extraBytes As Integer) as Ptr
    Declare Sub objc_registerClassPair Lib "Cocoa" (cls As Ptr)
    Declare Function class_addMethod Lib "Cocoa" (cls As Ptr, name As Ptr, imp As Ptr, types As CString) As Boolean
    
    // 既にインスタンス作成済なら、それを返す
    if SearchDelegateInstance <> nil then
      return SearchDelegateInstance
    end if
    
    // クラス名を引数のname（名前は任意だが、重複を避けるためにアイテムのIdentifierにしている。）、メタクラス名をNSObjectにして、生成
    Dim newClassId As Ptr = objc_allocateClassPair(NSClassFromString("NSObject"), name, 0)
    // ランタイムに登録（参照を可能とするため）
    objc_registerClassPair newClassId
    // Delegateの対象となるメソッドを追加（control:textView:doCommandBySelector:をXojo側で用意したcontrolTextViewDoCommandBySelectorメソッドで受け取る。）
    if not class_addMethod (newClassId, NSSelectorFromString("control:textView:doCommandBySelector:"), AddressOf controlTextViewDoCommandBySelector, "v@:@@@") then
      msgBox "error."
      return nil
    end if
    
    // 上記で生成したクラスのインスタンスを作成
    Declare Function alloc Lib "Cocoa" selector "alloc" (class_id As Ptr) As Ptr
    Declare Function init Lib "Cocoa" selector "init" (obj_id As Ptr) As Ptr
    Dim delegateId As Ptr = init(alloc(newClassId))
    
    // インスタンスを保持
    SearchDelegateInstance = delegateId
    
    // インスタンスを返す
    return delegateId
  End Function
  

• Window1に以下のメソッドを追加（復活）（注：本来の仕様である、戻り値を設定している点が、オリジナルと異なります。）

  Private Shared Function controlTextViewDoCommandBySelector(id As Ptr, sel As Ptr, control As Ptr, textView As Ptr, command As Ptr) as Boolean
    Dim mb As MemoryBlock
    mb = command
    if mb.CString(0) = "insertNewline:" then  // retunキーが押された
      
      // インスタンス側でActionを受け取るメソッドをレイズする
      ActionHandler.Invoke(control)
      
      return true  // trueを返さなくても、機能に問題はなさそう？
    end if
    
    // retunキー以外のキーではfalseを返す（これにより、サーチフィールドでdelete(backspace)キーが効かなくなる現象を回避）
    return false
  End Function
  

---

[Home]　 [MacSoft]　 [Donation]　 [History]　 [Privacy Policy]　 [Affiliate Policy]